home *** CD-ROM | disk | FTP | other *** search
/ Wonky Flux Batch 2019 02 / Wonky_Flux_Batch_2019-02.zip / Wonky Flux Batch 2019-02 / 058 - Algebra Workshop.dsk / SET.EPBH2.0.DEF.bas < prev    next >
BASIC Source File  |  2019-02-17  |  5KB  |  96 lines
  1. 5  ONERR  GOTO 10000
  2. 10 : REM  Reconfigure Enhanced PBH2.0
  3. 20 : REM  for default Device Slot/Drive
  4. 30 : REM  and Pathname
  5. 40 : REM  3 Apr 88 
  6. 50  PRINT  CHR$(4)"PR#3"
  7. 55  GOSUB 1100
  8. 60 PGM$ = "EPBH":VER$ = "2.0"
  9. 70 FI$ = PGM$ +VER$:: REM    File name  
  10. 75  VTAB 10:BS$ = "Hang on looking for " +FI$: GOSUB 1000
  11. 80  PRINT  CHR$(4)"bload "FI$",a$2000,l$50,tsys": REM  load part of file
  12. 85 D =  PEEK(8195):DD = 1: IF D >128  THEN DD = 2:D = D -128
  13. 90 DS = D/16
  14. 95 DP$ = "":L =  PEEK(8196): FOR I = 1 TO L:DP$ = DP$ + CHR$( PEEK(8196 +I)): NEXT 
  15. 100  GOSUB 1100
  16. 110  VTAB 4:BS$ = "Setting defaults for:" +FI$: GOSUB 1000
  17. 120  VTAB 6
  18. 124 BS$ = "Default Device set for: Slot:" + STR$(DS) +", Drive:" + STR$(DD): GOSUB 1000: PRINT 
  19. 126 BS$ = "Default Path set for:" +DP$: GOSUB 1000: PRINT : PRINT : PRINT 
  20. 130 BS$ = "Set default [P]ath  ": GOSUB 1000: PRINT 
  21. 140 BS$ = "Set default [D]evice": GOSUB 1000: PRINT 
  22. 150 BS$ = "[Q]uit to BASIC": GOSUB 1000: PRINT 
  23. 160 BS$ = "[B]ye": GOSUB 1000: PRINT 
  24. 170  PRINT : PRINT :BS$ = "Select [?]": GOSUB 1010: PRINT  CHR$(8); CHR$(8);
  25. 180  GET A$
  26. 190 A =  ASC(A$): IF A >91  THEN A = A -32:A$ =  CHR$(A)
  27. 200  IF A$ = "P"  THEN  GOTO 500
  28. 210  IF A$ = "D"  THEN  GOTO 300
  29. 220  IF A$ = "Q"  THEN  GOTO 280
  30. 230  IF A$ = "B"  THEN  GOTO 290
  31. 240  PRINT  CHR$(7);: GOTO 180
  32. 280 : PRINT A$: VTAB 23: END 
  33. 290 : PRINT A$: PRINT : PRINT  CHR$(4)"bye"
  34. 291  END 
  35. 300 : REM  Set Device
  36. 310  GOSUB 1100
  37. 330  VTAB 10: HTAB 10: PRINT "Enter Default Device Slot:";DS; CHR$(8);
  38. 340  GET A$
  39. 345  IF A$ =  CHR$(13)  THEN A$ =  STR$(DS)
  40. 347  IF A$ =  CHR$(27)  THEN  GOSUB 1100: GOTO 75
  41. 350 S =  VAL(A$): IF S <1  OR S >7  THEN  PRINT  CHR$(7);: GOTO 340
  42. 360  PRINT A$
  43. 370  VTAB 12: HTAB 10: PRINT "Enter Default Device Drive:";DD; CHR$(8);
  44. 380  GET A$
  45. 385  IF A$ =  CHR$(13)  THEN A$ =  STR$(DD)
  46. 387  IF A$ =  CHR$(27)  THEN  RUN 
  47. 390 DR =  VAL(A$): IF DR <1  OR DR >2  THEN  PRINT  CHR$(7);: GOTO 380
  48. 400  PRINT A$
  49. 410  IF DR = 2  THEN D = 128
  50. 415  IF DR = 1  THEN D = 0
  51. 420 DEV = (16 *S) +D: POKE 8195,DEV:: REM Default Device into Memory
  52. 430  PRINT : HTAB 10: PRINT "Set Default for: Slot ";S;", Drive ";DR;" [?]"; CHR$(8); CHR$(8);
  53. 440  GET A$
  54. 450  IF A$ = "n"  OR A$ = "N"  THEN  PRINT  CHR$(7): GOTO 490
  55. 460  IF A$ < >"y"  AND A$ < >"Y"  THEN  PRINT  CHR$(7);: GOTO 440
  56. 470  PRINT A$
  57. 480  PRINT : PRINT :BS$ = "Saving Default Path of:Slot " + STR$(S) +", Drive " + STR$(DR): GOSUB 1000
  58. 485  PRINT  CHR$(4)"bsave "FI$",b$3,a$2003,l$1,tsys"
  59. 490  GOSUB 1100: GOTO 75
  60. 500 : REM   Set Path
  61. 510  GOSUB 1100
  62. 520  VTAB 7: HTAB 10: PRINT "Current Default Path is:";DP$
  63. 530  VTAB 10: HTAB 10: INPUT "Enter Default Path:/";DP$
  64. 533  IF  LEFT$(DP$,1) < >"/"  THEN DP$ = "/" +DP$
  65. 540  FOR I = 1 TO  LEN(DP$): POKE (8196 +I), ASC( MID$ (DP$,I,1)): NEXT 
  66. 545  POKE 8196, LEN(DP$)
  67. 550  FOR I = 1 TO  LEN(DP$):B =  PEEK(8196 +I): IF B >90  THEN  POKE (8196 +I),(B -32)
  68. 555  NEXT :DP$ = ""
  69. 560 L =  PEEK(8196): FOR I = 1 TO L:DP$ = DP$ + CHR$( PEEK(8196 +I)): NEXT 
  70. 570  PRINT : PRINT : HTAB 10: PRINT "Set Default Path to:";DP$;" [?]"; CHR$(8); CHR$(8);
  71. 572  GET A$
  72. 575  IF A$ = "n"  OR A$ = "N"  THEN  PRINT  CHR$(7): GOTO 600
  73. 577  IF A$ < >"y"  AND A$ < >"Y"  THEN  PRINT  CHR$(7);: GOTO 572
  74. 578  PRINT A$
  75. 580 L = L +1: FOR I = L TO 65 -L: POKE (8196 +I),0: NEXT 
  76. 585  PRINT : PRINT :BS$ = "Saving Default Path of:" +DP$: GOSUB 1000
  77. 590  PRINT  CHR$(4)"bsave "FI$",b$4,a$2004,L$41,tsys"
  78. 600  GOSUB 1100: GOTO 75
  79. 999  END 
  80. 1000  HTAB (41 -( LEN(BS$)/2)): PRINT BS$: RETURN 
  81. 1005  PRINT : PRINT "Error number:" PEEK(222)" in line number:"(( PEEK(219) *256) + PEEK(218)" whatever the Hell that means!"; CHR$(7)
  82. 1010  HTAB (41 -( LEN(BS$)/2)): PRINT BS$;: RETURN 
  83. 1100  HOME 
  84. 1110  PRINT :BS$ = "Enhanced PBH version 2.0 Default Installation Program": GOSUB 1000: RETURN 
  85. 10000  VTAB 20
  86. 10010  IF  PEEK(222) = 10  THEN BS$ = FI$ +" is locked. Unlock it and type RUN to restart.": GOSUB 1000: END 
  87. 10020  IF  PEEK(222) = 6  THEN BS$ = "Can't seem to locate " +FI$ +" how about re-setting the prefix and try again.": GOSUB 1000: END 
  88. 10025  IF  PEEK(222) = 4  THEN BS$ = FI$ +" appears to be locked. Unlock the sucker and try again.": GOSUB 1000: END 
  89. 10030  IF  PEEK(222) = 8  THEN BS$ = "Seems we got an I/O Error that time.": GOSUB 1000: END 
  90. 10040  PRINT "Well I give up!": PRINT : FOR T = 1 TO 2000: NEXT : PRINT "Seems we have an error!"; CHR$(7): FOR T = 1 TO 1000: NEXT : PRINT : PRINT "Error number";
  91. 10043  FOR I = 1 TO 2000: NEXT 
  92. 10045  GOSUB 10100: PRINT "uh";: GOSUB 10100: PRINT "er";: GOSUB 10100: FOR I = 1 TO 1000: NEXT : PRINT "Ok!" CHR$(7)
  93. 10047  FOR I = 1 TO 2000: NEXT 
  94. 10050  PRINT : PRINT "Error number:"; PEEK(222);" in line number:";(( PEEK(219) *256) + PEEK(218));".    Whatever the Hell that means!"; CHR$(7)
  95. 10099  END 
  96. 10100  FOR T = 1 TO 1000: NEXT : FOR I = 1 TO 4: FOR T = 1 TO 200: NEXT T: PRINT ".";: NEXT I: FOR T = 1 TO 1000: NEXT : RETURN